Apple Reference & Presen…tion Library 4 (Reseller)/Apple Ref. & Pres. Lib.v4.0.iso/4-Demos/Apple Demos/Tutorials/Display Card 4•8⁄8•24 Training/Display Card 4•8_8•24 Training/stack.txt

Text File | 1990-03-19 | 8KB | 219 lines

-- stack: in
-- format: 8 (HyperCard 1)
-- flags: 0x1000 (none)
-- protect password hash: 0
-- maximum user level: 5 (scripting)
-- window: Rect(x1=0, y1=0, x2=0, y2=0)
-- screen: Rect(x1=0, y1=0, x2=0, y2=0)
-- card dimensions: w=0 h=0
-- scroll: x=0 y=0
-- background count: 18
-- first background id: 2792
-- card count: 121
-- first card id: 3041
-- list block id: 24793
-- print block id: 3519
-- font table block id: 0
-- style table block id: 0
-- free block count: 3
-- free size: 5952 bytes
-- total size: 294912 bytes
-- stack block size: 8704 bytes
-- created by hypercard version: 0x01228000
-- compacted by hypercard version: 0x01228000
-- modified by hypercard version: 0x01228000
-- opened by hypercard version: 0x01228000
-- patterns[0]: 0x0000000000000000
-- patterns[1]: 0x8000000008000000
-- patterns[2]: 0x8800220088002200
-- patterns[3]: 0x8888222288882222
-- patterns[4]: 0x88AA22AA88AA22AA
-- patterns[5]: 0xCCAA33AACCAA33AA
-- patterns[6]: 0xEEAABBAAEEAABBAA
-- patterns[7]: 0xEEBBBBEEEEBBBBEE
-- patterns[8]: 0xFFBBFFEEFFBBFFEE
-- patterns[9]: 0xFFBBFFFFFFBBFFFF
-- patterns[10]: 0x8010022001084004
-- patterns[11]: 0xFFFFFFFFFFFFFFFF
-- patterns[12]: 0x8822882288228822
-- patterns[13]: 0x1122448811224488
-- patterns[14]: 0xC4800C6843023026
-- patterns[15]: 0x0055004400550044
-- patterns[16]: 0xAA00AA00AA00AA00
-- patterns[17]: 0x8822552288225522
-- patterns[18]: 0x8855225588552255
-- patterns[19]: 0x77DD77DD77DD77DD
-- patterns[20]: 0x8000000000000000
-- patterns[21]: 0xAA55AA55AA55AA55
-- patterns[22]: 0x8888888888888888
-- patterns[23]: 0x0800220080002200
-- patterns[24]: 0x0814224180412214
-- patterns[25]: 0x8000080080000800
-- patterns[26]: 0xAA550000AA550000
-- patterns[27]: 0x8888888888888888
-- patterns[28]: 0x8844221188442211
-- patterns[29]: 0xCCCC3333CCCC3333
-- patterns[30]: 0x40A00000040A0000
-- patterns[31]: 0x8040200002040800
-- patterns[32]: 0x8800000080000000
-- patterns[33]: 0xAA00800080008000
-- patterns[34]: 0xFF80808080808080
-- patterns[35]: 0xFFFFFFFF00000000
-- patterns[36]: 0xF0F0F0F0F0F0F0F0
-- patterns[37]: 0xAAAAAAAAAAAAAAAA
-- patterns[38]: 0xFF00FF00FF00FF00
-- patterns[39]: 0xF0F0F0F00F0F0F0F
-- checksum: 0x0
----- HyperTalk script -----
--             Script of Stack "Macintosh Display Card 8/24"
--             Copyright © 1990 by Apple Computer, Inc.
---------------------------------------------------------------------
-- HyperCard construction — Cynthia Kolnick, Chuck Walker with additions
--            by Tom Hudson, Howard Bornstein and David Boardman
-- Functions: clickLine,
-- Handlers:  openStack, closeStack, arrowKey,
--            returnKey, enterKey, mouseUp, whatMenu,
--            resetMap, runningPause
-- Fonts:     Garamond 14, Garamond Italics 14, Garamond Bold 14,
--            Helvetica 18
-- Sounds:    Bell, Orchestral music from Apple CD-ROM Explorer
-- —————————————————————————————————————————————————————————————————
on openStack
  global mapLoc, cardLoc
  -- mapLoc tracks location by section name
  -- cardLoc tracks location by the number of the card name
  set cursor to watch
  if the version < 1.2 then
    answer "This stack requires HyperCard version 1.2." with "Continue" or "Home"
    if it is "Home" then domenu home
  end if
  put item 2 of the screenRect into screenTop
  if top of card window < screenTop + 20 then hide menuBar
  hide tool window
  hide pattern window
  hide menubar
  hide msg
  resetMap
  if cd fld "WhereWasI" ≠ "" then
    put cd fld "WhereWasI" into WhereWasI
    put "" into cd fld "WhereWasI"
    visual effect dissolve
    answer "Do you want to return to where you left off?" with "No" or "Yes"
    if it is "Yes" then go card WhereWasI
  end if
end openStack
--————————————————————————————————————————————————————————————————————
on closeStack
  answer "Do you want to save your place?" with "Yes" or "No"
  if it is "No" then put empty into field "footprints" of card "Map"
  else
    put "saved" into line 13 of field "footprints" of card "Map"
    put short name of this card into cd fld "WhereWasI" of card "open 0"
  end if
  pass closeStack
end closeStack

--————————————————————————————————————————————————————————————————————
--  intercept keyboard handlers:
--  same as clicking the arrow buttons
on arrowKey whatKey
  if whatKey = "Left" then click at 442,328
  if whatKey = "Right" then click at 469,328
end arrowKey

--  same as clicking the return button
on returnKey
  click at 498,328
end returnKey

--  intercept enter key
on enterKey
end enterKey

--————————————————————————————————————————————————————————————————————
-- help dialog, customized for various locations in the stack
on mouseUp
  visual dissolve
  push card
  if word 1 of the short name of this card = "content" then
    answer "Click on a card in the section or the map." with "Help" or "OK"
    if it is "help" then go card "help 2"
    else exit mouseup
  end if
  if word 1 of the short name of this card = "index" then
    answer "Click on a subheading or Arrow button." with "Help" or "OK"
    if it is "Help" then go card "howToUse"
    else exit mouseUp
  end if
  if word 1 of the short name of this card ≠ "test" then
    answer "Click one of the Arrow buttons." with "Help" or "OK"
    if it is "Help" then go card "howToUse"
    else exit mouseUp
  end if
end mouseUp

--————————————————————————————————————————————————————————————————————
-- disable certain menu options which are not appropriate  ———————————

on domenu menu                       --// Added by Medior, Inc. 2/20/90
  global RPStackName
  if menu is in "Home,Quit HyperCard" and RPStackName is not empty then
    set cursor to watch
    put RPStackName into shortname
    repeat until offset(":",shortname) = 0
      delete char 1 to offset(":",shortname) of shortname
    end repeat
    delete last char of shortname
    answer "This will return to "&shortname&"." with "Cancel" or "OK"
    if it is "Cancel" then exit domenu
    set cursor to watch
    lock screen
    go RPStackName
    unlock screen with dissolve
    exit domenu
  else if menu is in "Message Find... Print Report... Last Prev Next" then exit to HyperCard
  pass domenu
end domenu

--————————————————————————————————————————————————————————————————————
--  handler resets map to no footprints
on resetMap
  set lockMessages to true
  set lockRecent to true
  lock screen
  push card
  go card "Map"
  if line 13 of field "footprints" ≠ "saved" then
    repeat with x = 1 to 12
      set the style of bkgnd button x to opaque
    end repeat
    put "" into fld "footprints"
  end if
  pop card
  set lockMessages to false
  set lockRecent to false
  unlock screen
end resetMap

--————————————————————————————————————————————————————————————————————
--  timing for all animation events
on runningPause
  repeat 250
    if the mouse is down then
      click at the clickloc
      exit to HyperCard
    end if
  end repeat
end runningPause

-- Functions ——————————————————————————————————————————————————————————
function clickLine
-- Controls item selection in self-check evaluations
get the clickloc
put item 2 of it into theMouseY
return ((themouseY - item 2 of the rect of the target-4) div the textheight of the target) + 1
end clickLine

--  End Stack Script  ————————————————————————————————————————————————